home *** CD-ROM | disk | FTP | other *** search
/ Your Apple Games Gallery 1 / Your Apple Games Gallery (Side A)(MicroSPARC, Inc.)(1988).do / TITAN.CRONUS.bas < prev    next >
BASIC Source File  |  2021-12-11  |  3KB  |  55 lines
  1. 10  REM **********************
  2. 20  REM * TITAN CRONUS       *
  3. 30  REM * BY WILLIAM PU      *
  4. 40  REM * COPYRIGHT (C) 1985 *
  5. 50  REM * BY MICROSPARC, INC *
  6. 60  REM * CONCORD, MA  01742 *
  7. 70  REM **********************
  8. 80 CT = 25863:HS = 25900:SC = 25894
  9. 90  HOME : VTAB 12: INVERSE :A$ = " PROGRAM LOADING IN PROGRESS ": GOSUB 450: NORMAL : PRINT  CHR$(4)"BLOAD CRONUS,A$8000"
  10. 100  PRINT  CHR$(4)"BLOAD CRONUS.SHAPES,A$6A00"
  11. 110  PRINT  CHR$(4)"BLOAD CRONUS.ALPHA,A$6000"
  12. 120  FOR I = 0 TO 2: POKE SC +I,0: POKE HS +I,0: NEXT : REM CLEAR SCORES
  13. 130  TEXT : HOME : GOSUB 480: GOSUB 510
  14. 140 A$ = "TITAN CRONUS ": PRINT : PRINT : INVERSE : GOSUB 450: NORMAL 
  15. 150  PRINT :A$ = "BY WILLIAM PU": GOSUB 450
  16. 160 A$ = "DEDICATED TO YUK": GOSUB 450
  17. 170 A$ = "(C) 1985 BY MICROSPARC, INC.": GOSUB 450
  18. 180  PRINT :A$ = "CYCLOPS.....50": GOSUB 450
  19. 190 A$ = "CHIMERA....100": GOSUB 450
  20. 200 A$ = "ERINYES....500": GOSUB 450
  21. 210 A$ = "HALBERD....250": GOSUB 450
  22. 220  PRINT :A$ = "EXTRA SHIP AFTER EVERY LEVEL": GOSUB 450
  23. 230  PRINT : PRINT "PRESS '";: INVERSE : PRINT "K";: NORMAL : PRINT "' FOR KEYBOARD, '";: INVERSE : PRINT "P";: NORMAL : PRINT "' FOR PADDLES"
  24. 240 A$ = "  'A'   FIRE           <BUTTON>   FIRE ": GOSUB 450: REM 2/3/11/3/1 SPACES
  25. 250 A$ = "  <-    LEFT           <PDL(0)>   MOVE ": GOSUB 450: REM 2/4/11/3/1 SPACES
  26. 260 A$ = "  ->    RIGHT                          ": GOSUB 450: REM 2/4/26 SPACES
  27. 270  PRINT  TAB( 9)"PRESS '";: INVERSE : PRINT "Q";: NORMAL : PRINT "' TO EXIT GAME"
  28. 280  PRINT : PRINT "<ESC> HOLD GAME,<CTRL-K> SWITCH CONTROLS"
  29. 290  VTAB 23:A$ = "<CTRL-R> TO RESTART": GOSUB 450
  30. 300  VTAB 16: HTAB 26: GET A$
  31. 310  IF A$ = "Q"  THEN  TEXT : HOME : END 
  32. 320  IF A$ = "K"  THEN  POKE CT,1: CALL 32768: GOTO 350
  33. 330  IF A$ = "P"  THEN  POKE CT,0: CALL 32768: GOTO 350
  34. 340  GOTO 300
  35. 350  FOR I = 2 TO 0  STEP  -1: IF  PEEK(SC +I) =  PEEK(HS +I)  THEN  NEXT : GOTO 400
  36. 360  IF  PEEK(SC +I) < =  PEEK(HS +I)  THEN 400
  37. 370  TEXT : HOME : VTAB 12:A$ = "CONGRATULATIONS!!!": GOSUB 450:A$ = "YOU GOT THE HIGH SCORE!": FOR I = 0 TO 2: POKE HS +I, PEEK(SC +I): NEXT 
  38. 380  GOSUB 450
  39. 390  PRINT : PRINT : PRINT  TAB( 10)"NEW ";: GOSUB 480
  40. 400  VTAB 21: HTAB 1: PRINT "PRESS <RETURN> OR BUTTON TO CONTINUE": POKE  -16368,0: FOR I = 0 TO 1  STEP 0:I = ( PEEK( -16384) >127) +( PEEK( -16287) >127): NEXT 
  41. 410 I1 =  PEEK( -16384): IF I1 = 203  THEN A$ = "K": GOTO 320
  42. 420  IF I1 = 208  THEN A$ = "P": GOTO 330
  43. 430  IF  PEEK( -16287) >127  THEN A$ = "P": GOTO 330
  44. 440  GOTO 130
  45. 450 A =  LEN(A$)/2: IF A <19  THEN  HTAB 20 -A
  46. 460  PRINT A$: RETURN 
  47. 470  REM  PRINT HI SCORE
  48. 480  PRINT "HI SCORE: ";: FOR I = HS +2 TO HS  STEP  -1:S =  PEEK(I): GOSUB 530: NEXT 
  49. 490  RETURN 
  50. 500  REM  PRINT SCORE
  51. 510  VTAB 1: HTAB 25: PRINT "SCORE: ";: FOR I = SC +2 TO SC  STEP  -1:S =  PEEK(I): GOSUB 530: NEXT 
  52. 520  RETURN 
  53. 530 D1 =  INT(S/16):D2 = S -16 *D1: REM  SEPARATE INTO 2 NIBBLES
  54. 540  PRINT D1;D2;
  55. 550  RETURN